.include "tn85def.inc"

; One LED clock V1.0
; Mike Ingle <mike at opengpstracker dot org>
; Atmel ATTINY25/45/85
; PORTB0 - LED out Red, 470 ohm resistor in series with LED
; PORTB1 - LED out Green
; PORTB2 - switch common
; Hours button PORTB2 - PORTB0 with 470 ohm resistor
; Minutes button PORTB2 - PORTB1 with 470 ohm resistor
; Timing set for 4MHz crystal and CKDIV8 (500 KHz)
; This is open source software.

; Uncomment to blink 15-minute intervals instead of 5-minute intervals
#define	OPTION_FIFTEEN_MIN = 0

.def	REG_SUBSECONDS = r0 ; sub-second counting register
.def	REG_SECONDS = r1 ; seconds counting register
.def	REG_MINUTES = r2 ; minutes counting register, 0-4
.def	REG_MINUTES_COPY = r3 ; copy for displaying
.def	REG_FIVEMIN = r4 ; five-minute counting register, 0-11
.def	REG_FIVEMIN_COPY = r5 ; copy for displaying
.def	REG_HOURS = r6 ; hours counting register, 1-12
.def	REG_HOURS_COPY = r7 ; copy for displaying
.def	REG_BLINK_DELAY = r8 ; countdown for pausing
.def	REG_SHOW_MINUTES = r9 ; nonzero = show minutes, 0xff = latch show minutes
.def	REG_DEBOUNCE = r10 ; key debounce

.def	SCRATCH0 = r16
.def	SCRATCH1 = r17
;.def	SCRATCH2 = r18
.equ	PORT_LED = PORTB
.equ	PIN_LED = PINB
.equ	PORT_LED_RED = PORTB0
.equ	PORT_LED_GREEN = PORTB1
.equ	PORT_SWITCH_COMMON = PORTB2

; Note these are defined in order such that a shift left handles most state transitions.
; Change the order at your own risk.
.def	FLAGS1 = r19
.equ	FLAG1_PAUSE_HOURS = 0
.equ	FLAG1_BLINK_HOURS = 1
.equ	FLAG1_PAUSE_FIVEMIN = 2
.equ	FLAG1_BLINK_FIVEMIN = 3
.equ	FLAG1_PAUSE_MINUTES = 4
.equ	FLAG1_BLINK_MINUTES = 5

.def	FLAGS2 = r20
.equ	FLAG2_SWH_DOWN = 0
.equ	FLAG2_SWM_DOWN = 1
.equ	FLAG2_SW_DEBOUNCED = 2
.equ	FLAG2_SW_DEBOUNCE = 3
.equ	FLAG2_LED_YELLOW = 4

.org	0x0
	rjmp	V_RESET
	rjmp	V_INT0
	rjmp	V_PCINT0
	rjmp	V_TIMER1_COMPA
	rjmp	V_TIMER1_OVF
	rjmp	V_TIMER0_OVF
	rjmp	V_EE_RDY
	rjmp	V_ANA_COMP
	rjmp	V_ADC
	rjmp	V_TIMER1_COMPB
	rjmp	V_TIMER0_COMPA
	rjmp	V_TIMER0_COMPB
	rjmp	V_WDT
	rjmp	V_USI_START
	rjmp	V_USI_OVF
	
V_RESET:
V_ADC:
V_INT0:
V_PCINT0:
V_TIMER1_COMPA:
V_TIMER1_OVF:
V_TIMER0_OVF:
V_EE_RDY:
V_ANA_COMP:
V_TIMER1_COMPB:
V_TIMER0_COMPB:
V_WDT:
V_USI_START:
V_USI_OVF:

; Stack pointer
	ldi	SCRATCH0,high(RAMEND)
	ldi	SCRATCH1,low(RAMEND)
	out	SPH,SCRATCH0 ; comment this out for ATTINY25
	out	SPL,SCRATCH1
; Init registers
	clr	REG_SUBSECONDS
	clr	REG_SECONDS
	clr	REG_MINUTES
	clr	REG_FIVEMIN
	clr	REG_HOURS
	inc	REG_HOURS
	clr	REG_DEBOUNCE
	clr	REG_SHOW_MINUTES
	clr	FLAGS1
	clr	FLAGS2
; Setup I/O
	sbi	ACSR,ACD ; save power
	ldi	SCRATCH0,1<<PORT_SWITCH_COMMON
	out	PORT_LED,SCRATCH0 ; set the pull-up on the switch line
	ldi	SCRATCH0,(1<<PORT_LED_RED)|(1<<PORT_LED_GREEN)
	out	DDRB,SCRATCH0 ; set LED lines to output
; Setup periodic interrupt on Timer0
	ldi	SCRATCH0,(1<<WGM01)
	out	TCCR0A,SCRATCH0 ; select CTC mode
	ldi	SCRATCH0,249 ; clock divisor
	out	OCR0A,SCRATCH0 ; 500000 / 8 / 250 = 250 interrupts per second	
	ldi	SCRATCH0,(1<<OCIE0A) ; enable compare match interrupt
	out	TIMSK,SCRATCH0
	ldi	SCRATCH0,(1<<CS01) ; divide clock by eight
	out	TCCR0B,SCRATCH0 ; activate clock
; --------------------------
;      interrupts on
; --------------------------
	sei
; 
MAIN:
	sleep
	rjmp MAIN ; no main program, interrupt does everything

;------------------------------------------------------------------
; Main interrupt, called 250 times per second
V_TIMER0_COMPA:
; Save the flags and stack here if we have a main program
; Reverse LEDs if yellow
	sbrs	FLAGS2,FLAG2_LED_YELLOW
	rjmp	LED_YELLOW_OUT
	in	SCRATCH0,PORT_LED
	ldi	SCRATCH1,(1<<PORT_LED_RED)|(1<<PORT_LED_GREEN)
	eor	SCRATCH0,SCRATCH1
	out	PORT_LED,SCRATCH0
LED_YELLOW_OUT:
; increment the time
	inc	REG_SUBSECONDS
	ldi	SCRATCH0,250
	cp	REG_SUBSECONDS,SCRATCH0
	brne	INCTIME_OUT
; whole second
	clr	REG_SUBSECONDS
	inc	REG_SECONDS
	ldi	SCRATCH0,60
	cp	REG_SECONDS,SCRATCH0
	brne	INCTIME_OUT
; whole minute
	clr	REG_SECONDS
	inc	REG_MINUTES
#ifdef	OPTION_FIFTEEN_MIN
	ldi	SCRATCH0,15
#else
	ldi	SCRATCH0,5
#endif
	cp	REG_MINUTES,SCRATCH0
	brne	INCTIME_OUT
; whole five-minutes
	clr	REG_MINUTES
	inc	REG_FIVEMIN
#ifdef	OPTION_FIFTEEN_MIN
	ldi	SCRATCH0,4
#else
	ldi	SCRATCH0,12
#endif
	cp	REG_FIVEMIN,SCRATCH0
	brne	INCTIME_OUT
; whole hour
	clr	REG_FIVEMIN
	inc	REG_HOURS
	ldi	SCRATCH0,13
	cp	REG_HOURS,SCRATCH0
	brne	INCTIME_OUT
; whole day
	ldi	SCRATCH0,1
	mov	REG_HOURS,SCRATCH0
INCTIME_OUT:

; Blink out the time
	sbrc	FLAGS1,FLAG1_PAUSE_HOURS
	rjmp	BLINK_PAUSE_HOURS
	sbrc	FLAGS1,FLAG1_BLINK_HOURS
	rjmp	BLINK_HOURS
	sbrc	FLAGS1,FLAG1_PAUSE_FIVEMIN
	rjmp	BLINK_PAUSE_FIVEMIN
	sbrc	FLAGS1,FLAG1_BLINK_FIVEMIN
	rjmp	BLINK_FIVEMIN
	sbrc	FLAGS1,FLAG1_PAUSE_MINUTES
	rjmp	BLINK_PAUSE_MINUTES
	sbrc	FLAGS1,FLAG1_BLINK_MINUTES
	rjmp	BLINK_MINUTES
	ldi	FLAGS1,1<<FLAG1_PAUSE_HOURS
	rjmp	BLINK_OUT
;
BLINK_PAUSE_HOURS:
	clz                      ; longer delay before hours
	sbrs	REG_SUBSECONDS,0 ; this makes it count half as fast
	dec	REG_BLINK_DELAY
	brne	BLINK_OUT_1
; done with pause hours, transition to blink hours
	lsl	FLAGS1 ; PAUSE_HOURS -> BLINK_HOURS
	mov	REG_HOURS_COPY,REG_HOURS
	mov	REG_FIVEMIN_COPY,REG_FIVEMIN
	mov	REG_MINUTES_COPY,REG_MINUTES
BLINK_OUT_1:
	rjmp	BLINK_OUT
;
BLINK_HOURS:
	tst	REG_HOURS_COPY
	brne	BHRS_NOTDONE
; done blinking hours, transition to pause minutes
	lsl	FLAGS1 ; BLINK_HOURS -> PAUSE_FIVEMIN
	ldi	SCRATCH0,250
	mov	REG_BLINK_DELAY,SCRATCH0
	rjmp	BLINK_OUT	
BHRS_NOTDONE:
	mov	SCRATCH0,REG_SUBSECONDS
	tst	SCRATCH0 ; is it zero?
	brne	BHRS_NZ
	sbi	PORT_LED,PORT_LED_RED ; light it red at zero
	cbi	PORT_LED,PORT_LED_GREEN
BHRS_NZ:
	cpi	SCRATCH0,125 ; is it half?
	brne	BHRS_NH
	cbi	PORT_LED,PORT_LED_RED ; light off at half
	cbi	PORT_LED,PORT_LED_GREEN
	dec	REG_HOURS_COPY
BHRS_NH:
	rjmp	BLINK_OUT
	
BLINK_PAUSE_FIVEMIN:
	dec	REG_BLINK_DELAY
	brne	BLINK_OUT
; done with pause fivemin, transition to blink fivemin
	lsl	FLAGS1 ; PAUSE_FIVEMIN -> BLINK_FIVEMIN
	mov	REG_BLINK_DELAY,REG_FIVEMIN
	rjmp	BLINK_OUT
;
BLINK_FIVEMIN:
	tst	REG_FIVEMIN_COPY
	brne	BFMN_NOTDONE
; done blinking fivemin, transition to pause minutes or next cycle
	cbr	FLAGS1,1<<FLAG1_BLINK_FIVEMIN
	tst	REG_SHOW_MINUTES ; is show minutes enabled?
	breq	BFMN_NEWCYCLE
	sbr	FLAGS1,1<<FLAG1_PAUSE_MINUTES
	rjmp	BFMN_SKIP
BFMN_NEWCYCLE:
	sbr	FLAGS1,1<<FLAG1_PAUSE_HOURS
BFMN_SKIP:
	ldi	SCRATCH0,250
	mov	REG_BLINK_DELAY,SCRATCH0
	rjmp	BLINK_OUT	
BFMN_NOTDONE:
	mov	SCRATCH0,REG_SUBSECONDS
	tst	SCRATCH0 ; is it zero?
	brne	BFMN_NZ
	sbi	PORT_LED,PORT_LED_GREEN ; light it green at zero
	cbi	PORT_LED,PORT_LED_RED
BFMN_NZ:
	cpi	SCRATCH0,125 ; is it half?
	brne	BFMN_NH
	cbi	PORT_LED,PORT_LED_GREEN
	cbi	PORT_LED,PORT_LED_RED ; light off at half
	dec	REG_FIVEMIN_COPY
BFMN_NH:
	rjmp	BLINK_OUT
;
BLINK_PAUSE_MINUTES:
	dec	REG_BLINK_DELAY
	brne	BLINK_OUT
; done with pause minutes, transition to blink minutes
	lsl	FLAGS1 ; PAUSE_MINUTES -> BLINK_MINUTES
	mov	SCRATCH0,REG_SHOW_MINUTES
	cpi	SCRATCH0,0xff ; means latched
	breq	BPM_SKIP1
	dec	REG_SHOW_MINUTES
BPM_SKIP1:
	rjmp	BLINK_OUT
;
BLINK_MINUTES:
	tst	REG_MINUTES_COPY
	brne	BMIN_NOTDONE
; done blinking minutes, transition to next cycle
	ldi	FLAGS1,1<<FLAG1_PAUSE_HOURS
	ldi	SCRATCH0,250
	mov	REG_BLINK_DELAY,SCRATCH0
	rjmp	BLINK_OUT	
BMIN_NOTDONE:
	mov	SCRATCH0,REG_SUBSECONDS
	tst	SCRATCH0 ; is it zero?
	brne	BMIN_NZ
	sbr	FLAGS2,1<<FLAG2_LED_YELLOW ; light it yellow at zero
	sbi	PORT_LED,PORT_LED_GREEN ; turn light on, will be reversed every interrupt
BMIN_NZ:
	cpi	SCRATCH0,125 ; is it half?
	brne	BMIN_NH
	cbr	FLAGS2,1<<FLAG2_LED_YELLOW
	cbi	PORT_LED,PORT_LED_GREEN
	cbi	PORT_LED,PORT_LED_RED ; light off at half
	dec	REG_MINUTES_COPY
BMIN_NH:
;	rjmp	BLINK_OUT
;
BLINK_OUT:
; 
; Check for keypresses
;
;
	mov	SCRATCH0,REG_SUBSECONDS
	andi	SCRATCH0,0x03
	brne	SCANKEYS_OUT_1 ; do this every fourth interrupt
;
	sbrs	FLAGS2,FLAG2_SW_DEBOUNCE
	rjmp	SCANKEYS_NOT_IN_DEBOUNCE
	cbr	FLAGS2,1<<FLAG2_SW_DEBOUNCE
	sbr	FLAGS2,1<<FLAG2_SW_DEBOUNCED
SCANKEYS_OUT_1:
	rjmp	SCANKEYS_OUT
SCANKEYS_NOT_IN_DEBOUNCE:
;
	in	SCRATCH0,PORT_LED
	ldi	SCRATCH1,1<<PORT_SWITCH_COMMON
	out	PORT_LED,SCRATCH1 ; set LED outputs to low simultaneously, bias switch common high
	nop
	nop	; wait for propagation
	sbis	PIN_LED,PORT_SWITCH_COMMON ; did the switch common get pulled down?
	rjmp	SCANKEYS_KEYDOWN
	out	PORT_LED,SCRATCH0 ; no key down; reset state of outputs
; No key down, was one just released?
	sbrs	FLAGS2,FLAG2_SWM_DOWN
	rjmp	SCANKEYS_NOT_SWM
	sbrs	FLAGS2,FLAG2_SWH_DOWN
	rjmp	SCANKEYS_SWM
;	rjmp	SCANKEYS_BOTH

; here both keys were pressed; toggle show minutes
SCANKEYS_BOTH:
	tst	REG_SHOW_MINUTES
	breq	SCANKEYS_SHOW_MINUTES_ON
	clr	REG_SHOW_MINUTES
	rjmp	SCANKEYS_RELEASED_OUT
SCANKEYS_SHOW_MINUTES_ON:
	dec	REG_SHOW_MINUTES ; it was previously zero so this makes it 0xff
	rjmp	SCANKEYS_RELEASED_OUT
;
; here SWM only was down, advance minutes and clear seconds
SCANKEYS_SWM:
	clr	REG_SECONDS
	inc	REG_MINUTES
#ifdef	OPTION_FIFTEEN_MIN
	ldi	SCRATCH0,15
#else
	ldi	SCRATCH0,5
#endif
	cp	REG_MINUTES,SCRATCH0
	brlo	SCANKEYS_NO_RESET_MINUTES
	clr	REG_MINUTES
	inc	REG_FIVEMIN
#ifdef	OPTION_FIFTEEN_MIN
	ldi	SCRATCH1,4
#else
	ldi	SCRATCH1,12
#endif
	cp	REG_FIVEMIN,SCRATCH1
	brlo	SCANKEYS_NO_RESET_MINUTES
	clr	REG_FIVEMIN
SCANKEYS_NO_RESET_MINUTES:
	mov	REG_SHOW_MINUTES,SCRATCH0 ; setting it to 5, wich was loaded above
	rjmp	SCANKEYS_RELEASED_OUT

SCANKEYS_NOT_SWM:
	sbrs	FLAGS2,FLAG2_SWH_DOWN
	rjmp	SCANKEYS_RELEASED_OUT
;	rjmp	SCANKEYS_SWH

; here SWH only was down, advance hours
SCANKEYS_SWH:
	inc	REG_HOURS
	ldi	SCRATCH0,13
	cp	REG_HOURS,SCRATCH0
	brlo	SCANKEYS_NO_RESET_HOURS
	clr	REG_HOURS
	inc	REG_HOURS
SCANKEYS_NO_RESET_HOURS:
	ldi	SCRATCH0,5
	mov	REG_SHOW_MINUTES,SCRATCH0
;	rjmp	SCANKEYS_RELEASED_OUT
;	
SCANKEYS_RELEASED_OUT:
	cbr	FLAGS2,(1<<FLAG2_SW_DEBOUNCED)|(1<<FLAG2_SWM_DOWN)|(1<<FLAG2_SWH_DOWN)
	rjmp	SCANKEYS_OUT
;
SCANKEYS_KEYDOWN:
	sbi	PORT_LED,PORT_LED_RED ; figure out which one
	nop
	nop	; wait for propagation
	sbis	PIN_LED,PORT_SWITCH_COMMON
	sbr	FLAGS2,1<<FLAG2_SWM_DOWN	
	cbi	PORT_LED,PORT_LED_RED 
	sbi	PORT_LED,PORT_LED_GREEN
	nop
	nop
	sbis	PIN_LED,PORT_SWITCH_COMMON
	sbr	FLAGS2,1<<FLAG2_SWH_DOWN	
	out	PORT_LED,SCRATCH0 ; reset state of outputs
;
	sbrc	FLAGS2,FLAG2_SWM_DOWN       ; set debounce if either
	sbr	FLAGS2,1<<FLAG2_SW_DEBOUNCE ; switch is down and
	sbrc	FLAGS2,FLAG2_SWH_DOWN       ; debounced flag not set
	sbr	FLAGS2,1<<FLAG2_SW_DEBOUNCE
	sbrc	FLAGS2,FLAG2_SW_DEBOUNCED
	cbr	FLAGS2,1<<FLAG2_SW_DEBOUNCE
;
SCANKEYS_OUT:
	reti

		

; EOF